无外部控件制作多媒体播放器(二)

控件|媒体

本来想写点进度控制与音量调整的代码的,后来发现还是太简单了,就是几个MCI命令,来回搬弄,自己都没兴趣写下去。所以我想还是写些独门一点的:音乐信息的读取!

目前常见的主流音乐格式就两种,MP3与WMA,它们都有在文件中保存音乐信息的特定格式,MP3使用的当然是家喻户晓的ID3格式,分为V1与V2两个版本;WMA是MS的宠儿,它只是ASF格式的一个分支,当然遵循ASF的包装规则。

怎么获取它们包含的音乐信息呢?一般是自己读取,当然XP系统开始提供了音乐文件的详细信息资料,利用FSO可以真接从系统那里读取到,这不在本文范围,毕竟不用控件更自由,通用性更好。所以,有必要去深入一下这几种音乐信息格式。还是用代码说话吧,先说说MP3的ID3V1与ID3V2的格式。

ID3V1很简单,共128个字节,写在文件尾部,格式如下:

Private Type Mp3ID3V1
    Header As String * 3
    Title As String * 30
    Artist As String * 30
    Album As String * 30
    Year As String * 4
    Comment As String * 30
    Genre As String * 1
End Type

ID3V2是后来出现的,可扩展性很强,写在文件头部,采用标签组格式,分两部分,一是标签组的总头部,一是每个子标签的头部,分别定义如下:

Private Type Mp3ID3V2
    Header As String * 3
    Ver As Byte
    Revision As Byte
    Flag As Byte
    Size(3) As Byte
End Type

Private Type Mp3ID3V2Tag
    Tag As String * 4
    Size(3) As Byte
    Flag(1) As Byte
End Type

为了组织音乐信息的方便,我还定义了一个自己的结构,以便于使用:

'音乐类型
Private Enum MediaType
    mciMIDI = 1
    mciMP3 = 2
    mciASF = 4
    mciVIDEO = 8
    mciWAVE = 16
End Enum
'装载音乐信息的结构
Private Type MusicInfo
    FileName As String
    MusicType As MediaType
    Title As String
    Artist As String
    Album As String
    Year As String
    Lyrics As String
    Writer As String
    Composer As String
    Bits As String
    Sample As String
    Length As Long
End Type

'我习惯于用代码说明问题,所以还是看看代码吧

Private Function GetMusicInfo(udtInfo As MusicInfo) As Boolean
    Dim strFileName As String, a() As String, i As Long
    With udtInfo
        strFileName = Dir(.FileName, vbNormal Or vbHidden Or vbReadOnly Or vbSystem Or vbArchive)
        If strFileName = vbNullString Then Exit Function
        .MusicType = GetMCIType(strFileName)
        If .MusicType And mciMP3 Then
            GetMusicInfo = GetMP3Info(udtInfo)
        ElseIf .MusicType And mciASF Then
            GetMusicInfo = GetASFInfo(udtInfo)
        End If
    End With
End Function

Private Function GetMCIType(strFileName As String) As MediaType
    Dim ext As String
    If strFileName <> vbNullString Then
        ext = LCase$(Mid$(strFileName, InStrRev(strFileName, ".")))
        Select Case ext
            Case ".mpg", ".mpeg", ".avi", ".mpe", ".mpa", ".m1v", ".ifo", ".vob"
                GetMCIType = mciVIDEO
            Case ".mp3"
                GetMCIType = mciMP3
            Case ".wav", ".snd", ".aif", ".au", ".aifc", ".aiff"
                GetMCIType = mciWAVE
            Case ".asf", ".wma", ".wm", ".wmd"
                GetMCIType = mciASF
            Case ".wmv"
                GetMCIType = mciASF Or mciVIDEO
            Case ".mid", ".midi", ".rmi"
                GetMCIType = mciMIDI
        End Select
    End If
End Function

Private Function GetMP3Info(udtInfo As MusicInfo) As Boolean
    Dim FreeNo As Long, n(1) As Byte, b() As Byte, TmpInfo As MusicInfo
    Dim Power As Long, v As Long, j As Long, Tagh As Mp3ID3V2Tag
    Dim id3 As Mp3ID3V1, s As String, Pos As Long, id32 As Mp3ID3V2
    Dim sz As Long, s1 As String
    TmpInfo = udtInfo
    On Error GoTo exitg
    FreeNo = FreeFile
    Open TmpInfo.FileName For Binary As #FreeNo
    With TmpInfo
        Pos = LOF(FreeNo) - 127
        If Pos > 0 Then
            Get #FreeNo, Pos, id3
            If UCase$(id3.Header) = "TAG" Then
                s = Trim$(Replace$(id3.Title, vbNullChar, vbNullString))
                If Len(s) > 0 Then
                    s = Replace$(s, "-", vbNullString)
                    s = Replace$(s, "——", vbNullString)
                    s = Replace$(s, ".mp3", vbNullString, , , vbTextCompare)
                    .Title = s
                End If
                s = Trim$(Replace$(id3.Artist, vbNullChar, vbNullString))
                If Len(s) > 0 Then
                    .Title = Replace$(.Title, s, vbNullString)
                    .Artist = s
                End If
                s = Trim$(Replace$(id3.Album, vbNullChar, vbNullString))
                If Len(s) > 0 Then .Album = s
                s = Trim$(Replace$(id3.Year, vbNullChar, vbNullString))
                If Len(s) > 0 Then .Year = s
            End If
        End If
        Get #FreeNo, 1, id32
        If id32.Header = "ID3" Then
            sz = (id32.Size(1) And &H7F) * &H400 + (id32.Size(2) And &H7F) * &H80 + (id32.Size(3) And &H7F)
            Pos = sz + 10
            s1 = String(4, vbNullChar)
            Get #FreeNo, , Tagh
            Do While Not (Tagh.Tag = s1 Or Seek(FreeNo) > sz + 10)
                j = Tagh.Size(1) * &H10000 + Tagh.Size(2) * &H100 + Tagh.Size(3)
                If j > 0 Then
                    ReDim b(j - 1)
                    Get #FreeNo, , b
                    s = StrConv(b, vbUnicode)
                    s = Trim$(Replace$(s, vbNullChar, ""))
                    Select Case Tagh.Tag
                    Case "TIT2"
                        .Title = s
                    Case "TPE1"
                        .Artist = s
                    Case "TALB"
                        .Album = s
                    Case "TCOM"
                        .Composer = s
                    Case "TEXT"
                        .Writer = s
                    Case "TYER"
                        .Year = s
                    Case "USLT"
                        s = Replace$(s, "  ", " ")
                        If LCase$(Left$(s, 3)) = "chi" Then
                            .Lyrics = Mid$(s, 4)
                        ElseIf LCase$(Left$(s, 3)) = "eng" Then
                            .Lyrics = Mid$(s, 4)
                        Else
                            .Lyrics = s
                        End If
                    End Select
                End If
                Get #FreeNo, , Tagh
            Loop
        Else
            Pos = 1
        End If
        Get #FreeNo, Pos, n
        sz = Pos
        If Not (n(0) = &HFF And n(1) >= &HFA And n(1) <= &HFF) Then
            Do While Not (n(0) = &HFF And n(1) = &HFB)
                Pos = Pos + 1
                If Seek(FreeNo) - sz > 8192 Then GoTo exitg
                Get #FreeNo, Pos, n
            Loop
        End If
        Get #FreeNo, , n
           
        v = 0
        For j = 4 To 7
            Power = 2 ^ j
            If (n(0) And Power) = Power Then v = v + Power
        Next
        v = v \ 16
        .Bits = Trim$(Mid$("144 320 32  48  56  64  80  96  112 128 160 192 224 256 320 ", v * 4 + 1, 4)) & "Kbps"
        v = 0
        For j = 2 To 3
            Power = 2 ^ j
            If (n(0) And Power) = Power Then v = v + Power
        Next
        v = v \ 4
        .Sample = Trim$(Mid$("44 48 32 ?? ", v * 3 + 1, 3)) & "KHz"
    End With
    udtInfo = TmpInfo
    GetMP3Info = True
exitg:
    Close #FreeNo
End Function

还有个ASF格式,有点烦,下篇再做说明吧!

时间: 2016-02-06

无外部控件制作多媒体播放器(二)的相关文章

无外部控件制作多媒体播放器(一)

控件|媒体 利用MCI指令制作播放器,简单实用,很适合于做为自己软件的一个附带功能或背景音乐,正是基于这点需求,我准备分几个部分来写: 1.MCI指令的简单使用:2.媒体播放的进度控制与音量调节:3.音乐信息的读取,包括MP3(ID3V1 & ID3V2)与ASF(WMA & WMV)等:4.音乐列表的建立与保存(M3U格式) 本来主要是想写播放音乐的,举个播放视频的例子,没什么别的意思,只是感觉播放音乐实在是简单,没什么可写,同时也是为了说明,MCI放视频也是可以的. Private C

无外部控件制作多媒体播放器(四)

控件|媒体 音乐文件列表也是个不容忽视的问题,自己定个格式当然可以,但好在大家熟悉的M3U格式并不复杂,MediaPlayer或WinAmp都支持它,通用性也好,比起wpl要简易得多,所以我就来介绍一下M3U格式文件的制作与读写 M3U是文本文件,以#EXTM3U开头,每个音乐条目占1-2行,当存在扩展信息时,首行采用#EXTINF:开头,第二行才是文件名:当没有扩展信息时,只是简单的一行,就是文件名:文件名可包含路径,也可不包含,不包含时音乐文件应该是与M3U文件在同一目录下. 整个格式就这么

无外部控件制作多媒体播放器(三)

控件|媒体 ASF全名为高级系统格式,是MS大力推宠的一种媒体格式,并已得到广泛支持.其最主要的分支就是用于音频的WMA与视频的WMV,当然还有ASF自身.在下面地址可下载到ASF格式的说明文档:http://www.microsoft.com/windows/windowsmedia/format/asfspec.aspx ASF格式由一个个不同功能的ASF对象组成,每个对象都有一个GUID做标识,你只需识别对象后,按对象格式读结构,就能找到你要的信息.媒体信息内容都在ASF头部对象ASF_H

vc++6 0-用vc++6.0 利用windows media player控件制作播放器时

问题描述 用vc++6.0 利用windows media player控件制作播放器时 在win7 64位环境下 要对 播放器进行暂停 快进等操作时 调用 CWMPcontrols 函数时 显示 'CWMPcontrols.h': No such file or directory 头文件 也加了 cwmpcontrols.h 头文件换成小写也是不行的 也说不能打开 没有这个文件 cwmpcontrols.h 头文件是存在的在工程目录下: 解决方案 你的VC++版本太旧,没有这个头文件.建议你

vs2008-VS2008制作多媒体播放器,WindowsMediaPlayer控件按钮出错

问题描述 VS2008制作多媒体播放器,WindowsMediaPlayer控件按钮出错 播放媒体后,按停止键(WindowsMediaPlayer),再将鼠标移至菜单栏(没有点击),立刻又继续播放 以下是部分代码: BOOL CPLAYERDlg::OnInitDialog() { CDialog::OnInitDialog(); SetIcon(m_hIcon, TRUE); // Set big icon SetIcon(m_hIcon, FALSE); // Set small icon

BCB控件制作和消息处理

1 前言 作为和delphi类似的rad(rapid application development)工具,c++ builder的强大功能不仅体现在数据库开发方面,也凸现于应用程序开发上(令人称绝的是这两方面结合得非常好).仅就应用程序而言,要真正体现c++ builder的优势,开发出高质量的软件,则在拖拉拽放之外,尚需用到一些进阶技术.如消息处理.dll.ole.线程.sdk编程.c++ builder在这些方面都或多或少有独到的优势.此外,可以方便地制作自定义控件,也是c++ build

wpf日历控件制作过程分析(2) 自定义样式属性

接上篇wpf日历控件制作过程分析(1) 定义header 在header中,我们看到了定义一个自定义样式TitleStyle 1.自定义样式 看后台代码定义 Code /**//// <summary> /// The DependencyProperty for the TitleStyle property. /// Flags: none /// Default Value: null /// </summary> public static readonly Depende

C/S模式开发中如何利用WebBrowser控件制作导航窗体

原文:C/S模式开发中如何利用WebBrowser控件制作导航窗体 转自: CSDN 相信不少同学们都做过MIS系统的开发,今天这里不讨论B/S模式开发的问题.来谈谈winform开发.用过市面上常见进销存系统的同学肯定知道,在进入系统之后一般在mdi窗体中系统自动打开一个导航子窗体.将一些常见的功能以非常直观的图形展示给用户.观察市面上的此类产品,该功能基本是所有mdi窗体开发的管理系统中必备的功能窗体.下面我们就来分析一下如何在.net中实现这个功能.幸好我上次做了一个类似的系统,里面也用到

Silverlight实用窍门系列:39.Silverlight中使用Frame和Page控件制作导航【附带实例源码】

在Silverlight中有时需要进入不同的XAML页面,但是一般情况下是不能实现"前进"和"后退"的,在这里我们可以使用Frame+Page控件制作导航功能实现上一页和下一页的跳转功能. 在本文中我们制作一个实例如下:添加一个Frame控件,然后点击"加载UC"和"加载PageShow"按钮加载UC.xaml和PageShow.xaml页面.在加载后我们可以通过鼠标右键菜单中的"上一页"和"下一