利用微软网格控件进行编辑输入

Visual Basic中提供了许多标准控件和定制控件,每一个控件都可以提供一组特殊的用户界面和编程能力。充分利用每一个控件的特性和方法,可以使编程工作更加容易、简单。

微软网格控件MSFlexGrid是个定制控件。使用微软网格控件,可以按行列顺序显示正文、数字和图片,就象电子表格一样。网格的高度、宽度和其它特性都可以进行调整,而且网格的行和列可以单个地或成组地进行操作。MSFlexGrid控件对包含在内的单元内容可进行分类、合并以及格式化,并且可以与数据库控件相绑定。MSFlexGrid控件具有50多种属性,比其它网格控件功能更强大,灵活性更强。

但是MSFlexGrid控件同其它Grid网格控件一样,用户不能编辑网格单元中的内容,在要求对其内容进行修改时,这可能是一个缺陷。虽然可以对DBGrid控件进行编程完成编辑的功能,但其功能不如MSFlexGrid强大。当在录入工作量比较大时,如果利用MSFlexGrid进行输入,代替Text或其它控件,从而避免了界面的反复刷新和不断地操作按钮,录入速度和效率会得以大大提高。

在应用程序中使用 MSFlexGrid 之前,应先将 MSFlxGrd.ocx 文件添加到工程中。

实现编辑网格单元的方案

为了仅仅要求实现能够对网格单元进行输入,可以在MSFlexGrid的KeyPress事件中加入以下代码,但是修改编辑输入后的内容还十分困难。

  Sub MSFLexGrid1_KeyPress(KeyAscii As Integer)
   MSFlexGrid1.Text=MSFlexGrid1.Text & Chr$(KeyAscii)
   End Sub

另外一种方法是文本框和网格相结合,用户编辑操作文本框中的内容,操作完后移至网格单元中。在这个过程中,应该实现以下几个功能:

(1)文本框能准确定位,与待编辑网格单元相重合(2)平时文本框不显示,当进行编辑操作时显示(3)在输入完一行后能自动判断并加一新行(4)按回车键确认并自动到下一列(5)双击网格单元可显示文本框进行编辑(6)文本框消失后,把文本框内容移到网格单元中。

编辑网格单元的具体实现

建立一个新工程,在Form1上添加控件 Text1和MSFlexGrid1,根据表1设置其属性。


表1 表单Form1的对象和属性

对象 属性 设置
Text1 Visible False
Text “”
MSFlexGrid1 Rows 2
Cols 根据字段数目自行设置
FixedCols 0
FixedRows 1

首先要实现文本框显示的时候,能与网格单元准确重合。ShowTextBox子例程便可以实现此功能。在此考虑网格本身的Top和Left值、网格单元的高度和宽度、分隔网格单元的边框的宽度。

  Sub ShowTextBox()
     With MSFlexGrid1
     '隐藏文本框,设置高度和宽度
     Text1.Visible = False
     Text1.Height = .RowHeight(.Row) - (Screen.TwipsPerPixelY) * 2
     Text1.Width = .ColWidth(.Col)
     ' 计算文本框左坐标
     Text1.Left = .CellLeft + .Left
     Text1.Top = .CellTop + .Top
     Text1.Visible = True
     Text1.SetFocus
   End With
   End Sub

当有按键触发网格单元时,则把单元中的内容保存到文本框中,然后显示文本框等待编辑。

  Private Sub MSFlexGrid1_KeyPress(KeyAscii As Integer)
   Dim char As String
   If KeyAscii = 13 Then
   Text1.Text = MSFlexGrid1.Text
     Text1.SelStart = Len(Text1.Text)
     Else
       char = Chr$(KeyAscii)
       Text1.Text = char
       Text1.SelStart = 1
     End If
     ShowTextBox
     KeyAscii = 0
   End Sub

当焦点离开一个网格单元时,先保存文本框中的内容到网格单元,然后检测离开单元是否在最大行第一列(可自己设第几列),如果是自动加一行。

  Private Sub MSFlexGrid1_LeaveCell()
     MSFlexGrid1.Text = Text1.Text
   If MSFlexGrid1.Col = 0 And MSFlexGrid1.Row <> 0 And _
   MSFlexGrid1.Row = MSFlexGrid1.Rows - 1 And MSFlexGrid1.Text <> "" Then
     MSFlexGrid1.Rows = MSFlexGrid1.Rows + 1
   End If
   End Sub

为了响应鼠标动作,添加以下代码。

  Private Sub MSFlexGrid1_MouseDown(Button As Integer, Shift As Integer, _
                   x As Single, y As Single)
   Text1.Visible = False
   End Sub

当网格单元发生变化时,取网格单元内容到文本框,等待编辑,从而保证文本框中的内容最新。

  Private Sub MSFlexGrid1_RowColChange()
   Text1.Text = MSFlexGrid1.Text
   End Sub

双击网格单元可以对网格单元中内容进行编辑。

  Private Sub MSFlexGrid1_DblClick()
   If MSFlexGrid1.Row > 0 And MSFlexGrid1.Col = 0 Then MSFlexGrid1_KeyPress 13
   End Sub

文本框起输入编辑框的作用,模拟网格单元,输入到文本框的内容,经过处理送到网格中,当输入完后按回车键可以自动到下一列,若为最后一列,跳转到下一行的第一列等待输入。

  Private Sub Text1_KeyPress(KeyAscii As Integer)
     If KeyAscii = 13 Then
       MSFlexGrid1.Text = Text1.Text
       Text1.Visible = False
       MSFlexGrid1.SetFocus
       If MSFlexGrid1.Col < (MSFlexGrid1.Cols - 1) Then
       MSFlexGrid1.Col = MSFlexGrid1.Col + 1
       ElseIf MSFlexGrid1.Row < MSFlexGrid1.Rows - 1 Then
         MSFlexGrid1.Row = MSFlexGrid1.Row + 1
         MSFlexGrid1.Col = 0
       End If
       KeyAscii = 0
     End If
   End Sub

以上程序在VB6.0 (中文企业版)下运行通过,实现了对MSFlexGrid网格单元的输入编辑。当然还可以添加一些代码完成对一些击键的响应,如按Tab自动到下一列,按Ese键取消输入等,这都很容易做到,在此不再叙述。如果您使用VB6.0 (中文企业版),还可以用MSHFlexGrid控件来完成编辑输入的功能。

时间: 2016-03-08

利用微软网格控件进行编辑输入的相关文章

ExtJs学习笔记(4)_EditorGridPanel(可编辑的网格控件)

这一节,我们将看到ExtJs功能强大的可编辑网格控件,几乎与VS.Net的GridView功能一样了,但是ExtJs的可是纯JS的UI 一.静态示例(改自ExtJs的官方示例) a.因为我们是采用xml做为数据源的,这里贴出xml的内容 Code <?xml version="1.0" encoding="utf-8"?> <catalog> <plant> <common>红竹</common> <

谁知道铁道部订票网哪个网格控件怎么做的?或者在哪可以下载那种控件?

问题描述 http://www.12306.cn/mormhweb/kyfw/ypcx/如题..........想找个功能强大的网格控件.......哪位同志帮忙介绍下...由于CSDN的插图做的比较纱布所以截的图没法传.提供了铁道部查票余的网格控件地址 解决方案 本帖最后由 t81lh 于 2012-03-30 09:07:20 编辑解决方案二:那个表格,自己写html码就行了,还要什么功能强大,想省事,gridview,datagrid都够你用了解决方案三:引用1楼的回复: 那个表格,自己写

ASP.NET:优化DataGrid控件的编辑功能

asp.net|datagrid|datagrid控件|优化 尽管在上面的实例中我们已经实现了DataGrid的在线编辑功能,但是,如果我们已经习惯了C/S 结构的程序,就会感觉到上个实例中编辑的不足:提交数据频繁,加重了服务器的负担.在这一节中,我们利用一个实例来演示优化后的DataGrid控件的编辑功能,其中的技术就是引入批量更新数据.引入的一个新知识就是控件的FindControl方法.     我们来看具体实例.首先在DataCon Web项目里,添加一个Web Form,命名为Data

在ASP中使用智岛网格控件全过程

过程|控件 在ASP中使用智岛网格控件全过程 -------------------------------------------------------------------------------- 智岛网格控件作为数据的表示层,可以非常方便的进行货币样式.人民币大小写.中文大小写.各种逻辑样式.百分比样式.千分位分割等样式设置:可以冻结.锁定行列.对输入数据进行验证:可对字段设置公式,方便快捷地统计.汇总数据.智岛网格控件以其丰富多样的表现形式.简单易用的操作赢得了广大软件开发人员的一

ASP.NET:DataList控件的选择输入功能

asp.net|控件     利用DataList控件的<SelectedItemTemplate> 属性,就可以随心所欲的布置表中的数据.根据链接,友好地显示出用户感兴趣的数据,我们来看下面的实例.     9.3.2 DataList控件的选择输入功能     在DataCon Web 项目里添加一个Web 窗体,命名为DataList_Sample2.aspx,添加一个DataList控件,DataList_Sample2.aspx的主要HTML代码如下: <form id=&qu

利用Aspose.Word控件实现Word文档的操作

原文:利用Aspose.Word控件实现Word文档的操作 Aspose系列的控件,功能都挺好,之前一直在我的Winform开发框架中用Aspose.Cell来做报表输出,可以实现多样化的报表设计及输出,由于一般输出的内容比较正规化或者多数是表格居多,所以一般使用Aspose.Cell来实现我想要的各种Excel报表输出.虽然一直也知道Aspose.Word是用来生成Word文档的,而且深信其也是一个很强大的控件,但一直没用用到,所以就不是很熟悉. 偶然一次机会,一个项目的报表功能指定需要导出为

改变 PropertyGrid 控件的编辑风格(4)——加入选择列表

改变 PropertyGrid 控件的编辑风格(4)--加入选择列表  张昱[email protected] 效果: 适用场合: 限制选择输入  步骤一:定义从UITypeEditor 继承的抽象类:ComboBoxItemTypeConvert.示例如下: using System; using System.Collections; using System.ComponentModel;  namespace blog.111cn.net.zhangyuk {      ///

利用Aspose.Cell控件导入Excel非强类型的数据

导入Excel的操作是非常常见的操作,可以使用Aspose.Cell.APOI.MyXls.OLEDB.Excel VBA等操作Excel文件,从而实现数据的导入,在导入数据的时候,如果是强类型的数据,那么这几种方式好像都表现差不多,正常操作能够导入数据.如果是非强类型的数据,那么就需要特别注意了,一般情况下,导入的DataTable数据列的类型是以第一行内容作为确定列类型的,本文介绍利用Aspose.Cell控件导入Excel非强类型的数据的操作. 什么是强类型的数据呢,就是在Excel表格中

改变 PropertyGrid 控件的编辑风格(1)——加入日期控件

控件 改变 PropertyGrid 控件的编辑风格(1)--加入日期控件   张昱[email protected]  效果: 适用场合: 编辑日期类型数据   步骤一:定义从UITypeEditor 派生的类,示例如下:   using System; using System.Windows.Forms; using System.Drawing.Design; using System.Windows.Forms.Design;   namespace blog.csdn.ne